jpmschweitzerandClaude
ce8529e424
Vendor libtree-sitter.so (v0.26.8, wasmtime 44.0 statically linked) and call its C API through dart:ffi. Grammar WASM files are loaded by tree-sitter's embedded wasmtime engine via ts_wasm_store_load_language. 48 grammars compiled with tree-sitter build --wasm, 48 highlight queries (42 from upstream repos, 6 written in-house for comment, erlang, gdscript, gitignore, hcl, hlsl, swift). SQLite grammar replaces full SQL (974K-line parser exhausted RAM at compile time). Removes wasm_run and wasm_run_flutter — they downloaded a 22 MB binary from GitHub at first launch, violating the no-network-on- default-launch-path policy. Co-Authored-By: Claude <noreply@anthropic.com>
205 lines
2.7 KiB
Scheme
205 lines
2.7 KiB
Scheme
; Variables
|
|
;----------
|
|
|
|
(identifier) @variable
|
|
|
|
; Properties
|
|
;-----------
|
|
|
|
(property_identifier) @property
|
|
|
|
; Function and method definitions
|
|
;--------------------------------
|
|
|
|
(function_expression
|
|
name: (identifier) @function)
|
|
(function_declaration
|
|
name: (identifier) @function)
|
|
(method_definition
|
|
name: (property_identifier) @function.method)
|
|
|
|
(pair
|
|
key: (property_identifier) @function.method
|
|
value: [(function_expression) (arrow_function)])
|
|
|
|
(assignment_expression
|
|
left: (member_expression
|
|
property: (property_identifier) @function.method)
|
|
right: [(function_expression) (arrow_function)])
|
|
|
|
(variable_declarator
|
|
name: (identifier) @function
|
|
value: [(function_expression) (arrow_function)])
|
|
|
|
(assignment_expression
|
|
left: (identifier) @function
|
|
right: [(function_expression) (arrow_function)])
|
|
|
|
; Function and method calls
|
|
;--------------------------
|
|
|
|
(call_expression
|
|
function: (identifier) @function)
|
|
|
|
(call_expression
|
|
function: (member_expression
|
|
property: (property_identifier) @function.method))
|
|
|
|
; Special identifiers
|
|
;--------------------
|
|
|
|
((identifier) @constructor
|
|
(#match? @constructor "^[A-Z]"))
|
|
|
|
([
|
|
(identifier)
|
|
(shorthand_property_identifier)
|
|
(shorthand_property_identifier_pattern)
|
|
] @constant
|
|
(#match? @constant "^[A-Z_][A-Z\\d_]+$"))
|
|
|
|
((identifier) @variable.builtin
|
|
(#match? @variable.builtin "^(arguments|module|console|window|document)$")
|
|
(#is-not? local))
|
|
|
|
((identifier) @function.builtin
|
|
(#eq? @function.builtin "require")
|
|
(#is-not? local))
|
|
|
|
; Literals
|
|
;---------
|
|
|
|
(this) @variable.builtin
|
|
(super) @variable.builtin
|
|
|
|
[
|
|
(true)
|
|
(false)
|
|
(null)
|
|
(undefined)
|
|
] @constant.builtin
|
|
|
|
(comment) @comment
|
|
|
|
[
|
|
(string)
|
|
(template_string)
|
|
] @string
|
|
|
|
(regex) @string.special
|
|
(number) @number
|
|
|
|
; Tokens
|
|
;-------
|
|
|
|
[
|
|
";"
|
|
(optional_chain)
|
|
"."
|
|
","
|
|
] @punctuation.delimiter
|
|
|
|
[
|
|
"-"
|
|
"--"
|
|
"-="
|
|
"+"
|
|
"++"
|
|
"+="
|
|
"*"
|
|
"*="
|
|
"**"
|
|
"**="
|
|
"/"
|
|
"/="
|
|
"%"
|
|
"%="
|
|
"<"
|
|
"<="
|
|
"<<"
|
|
"<<="
|
|
"="
|
|
"=="
|
|
"==="
|
|
"!"
|
|
"!="
|
|
"!=="
|
|
"=>"
|
|
">"
|
|
">="
|
|
">>"
|
|
">>="
|
|
">>>"
|
|
">>>="
|
|
"~"
|
|
"^"
|
|
"&"
|
|
"|"
|
|
"^="
|
|
"&="
|
|
"|="
|
|
"&&"
|
|
"||"
|
|
"??"
|
|
"&&="
|
|
"||="
|
|
"??="
|
|
] @operator
|
|
|
|
[
|
|
"("
|
|
")"
|
|
"["
|
|
"]"
|
|
"{"
|
|
"}"
|
|
] @punctuation.bracket
|
|
|
|
(template_substitution
|
|
"${" @punctuation.special
|
|
"}" @punctuation.special) @embedded
|
|
|
|
[
|
|
"as"
|
|
"async"
|
|
"await"
|
|
"break"
|
|
"case"
|
|
"catch"
|
|
"class"
|
|
"const"
|
|
"continue"
|
|
"debugger"
|
|
"default"
|
|
"delete"
|
|
"do"
|
|
"else"
|
|
"export"
|
|
"extends"
|
|
"finally"
|
|
"for"
|
|
"from"
|
|
"function"
|
|
"get"
|
|
"if"
|
|
"import"
|
|
"in"
|
|
"instanceof"
|
|
"let"
|
|
"new"
|
|
"of"
|
|
"return"
|
|
"set"
|
|
"static"
|
|
"switch"
|
|
"target"
|
|
"throw"
|
|
"try"
|
|
"typeof"
|
|
"var"
|
|
"void"
|
|
"while"
|
|
"with"
|
|
"yield"
|
|
] @keyword
|