jpmschweitzerandClaude
ce8529e424
Vendor libtree-sitter.so (v0.26.8, wasmtime 44.0 statically linked) and call its C API through dart:ffi. Grammar WASM files are loaded by tree-sitter's embedded wasmtime engine via ts_wasm_store_load_language. 48 grammars compiled with tree-sitter build --wasm, 48 highlight queries (42 from upstream repos, 6 written in-house for comment, erlang, gdscript, gitignore, hcl, hlsl, swift). SQLite grammar replaces full SQL (974K-line parser exhausted RAM at compile time). Removes wasm_run and wasm_run_flutter — they downloaded a 22 MB binary from GitHub at first launch, violating the no-network-on- default-launch-path policy. Co-Authored-By: Claude <noreply@anthropic.com>
155 lines
2.3 KiB
Scheme
155 lines
2.3 KiB
Scheme
(identifier) @variable
|
|
|
|
((identifier) @function.method
|
|
(#is-not? local))
|
|
|
|
[
|
|
"alias"
|
|
"and"
|
|
"begin"
|
|
"break"
|
|
"case"
|
|
"class"
|
|
"def"
|
|
"do"
|
|
"else"
|
|
"elsif"
|
|
"end"
|
|
"ensure"
|
|
"for"
|
|
"if"
|
|
"in"
|
|
"module"
|
|
"next"
|
|
"or"
|
|
"rescue"
|
|
"retry"
|
|
"return"
|
|
"then"
|
|
"unless"
|
|
"until"
|
|
"when"
|
|
"while"
|
|
"yield"
|
|
] @keyword
|
|
|
|
((identifier) @keyword
|
|
(#match? @keyword "^(private|protected|public)$"))
|
|
|
|
(constant) @constructor
|
|
|
|
; Function calls
|
|
|
|
"defined?" @function.method.builtin
|
|
|
|
(call
|
|
method: [(identifier) (constant)] @function.method)
|
|
|
|
((identifier) @function.method.builtin
|
|
(#eq? @function.method.builtin "require"))
|
|
|
|
; Function definitions
|
|
|
|
(alias (identifier) @function.method)
|
|
(setter (identifier) @function.method)
|
|
(method name: [(identifier) (constant)] @function.method)
|
|
(singleton_method name: [(identifier) (constant)] @function.method)
|
|
|
|
; Identifiers
|
|
|
|
[
|
|
(class_variable)
|
|
(instance_variable)
|
|
] @property
|
|
|
|
((identifier) @constant.builtin
|
|
(#match? @constant.builtin "^__(FILE|LINE|ENCODING)__$"))
|
|
|
|
(file) @constant.builtin
|
|
(line) @constant.builtin
|
|
(encoding) @constant.builtin
|
|
|
|
(hash_splat_nil
|
|
"**" @operator) @constant.builtin
|
|
|
|
((constant) @constant
|
|
(#match? @constant "^[A-Z\\d_]+$"))
|
|
|
|
[
|
|
(self)
|
|
(super)
|
|
] @variable.builtin
|
|
|
|
(block_parameter (identifier) @variable.parameter)
|
|
(block_parameters (identifier) @variable.parameter)
|
|
(destructured_parameter (identifier) @variable.parameter)
|
|
(hash_splat_parameter (identifier) @variable.parameter)
|
|
(lambda_parameters (identifier) @variable.parameter)
|
|
(method_parameters (identifier) @variable.parameter)
|
|
(splat_parameter (identifier) @variable.parameter)
|
|
|
|
(keyword_parameter name: (identifier) @variable.parameter)
|
|
(optional_parameter name: (identifier) @variable.parameter)
|
|
|
|
; Literals
|
|
|
|
[
|
|
(string)
|
|
(bare_string)
|
|
(subshell)
|
|
(heredoc_body)
|
|
(heredoc_beginning)
|
|
] @string
|
|
|
|
[
|
|
(simple_symbol)
|
|
(delimited_symbol)
|
|
(hash_key_symbol)
|
|
(bare_symbol)
|
|
] @string.special.symbol
|
|
|
|
(regex) @string.special.regex
|
|
(escape_sequence) @escape
|
|
|
|
[
|
|
(integer)
|
|
(float)
|
|
] @number
|
|
|
|
[
|
|
(nil)
|
|
(true)
|
|
(false)
|
|
] @constant.builtin
|
|
|
|
(interpolation
|
|
"#{" @punctuation.special
|
|
"}" @punctuation.special) @embedded
|
|
|
|
(comment) @comment
|
|
|
|
; Operators
|
|
|
|
[
|
|
"="
|
|
"=>"
|
|
"->"
|
|
] @operator
|
|
|
|
[
|
|
","
|
|
";"
|
|
"."
|
|
] @punctuation.delimiter
|
|
|
|
[
|
|
"("
|
|
")"
|
|
"["
|
|
"]"
|
|
"{"
|
|
"}"
|
|
"%w("
|
|
"%i("
|
|
] @punctuation.bracket
|