jpmschweitzerandClaude
ce8529e424
Vendor libtree-sitter.so (v0.26.8, wasmtime 44.0 statically linked) and call its C API through dart:ffi. Grammar WASM files are loaded by tree-sitter's embedded wasmtime engine via ts_wasm_store_load_language. 48 grammars compiled with tree-sitter build --wasm, 48 highlight queries (42 from upstream repos, 6 written in-house for comment, erlang, gdscript, gitignore, hcl, hlsl, swift). SQLite grammar replaces full SQL (974K-line parser exhausted RAM at compile time). Removes wasm_run and wasm_run_flutter — they downloaded a 22 MB binary from GitHub at first launch, violating the no-network-on- default-launch-path policy. Co-Authored-By: Claude <noreply@anthropic.com>
205 lines
2.9 KiB
Scheme
205 lines
2.9 KiB
Scheme
; Keywords
|
|
"return" @keyword.return
|
|
|
|
[
|
|
"goto"
|
|
"in"
|
|
"local"
|
|
"global"
|
|
] @keyword
|
|
|
|
(label_statement) @label
|
|
|
|
(break_statement) @keyword
|
|
|
|
(do_statement
|
|
[
|
|
"do"
|
|
"end"
|
|
] @keyword)
|
|
|
|
(while_statement
|
|
[
|
|
"while"
|
|
"do"
|
|
"end"
|
|
] @repeat)
|
|
|
|
(repeat_statement
|
|
[
|
|
"repeat"
|
|
"until"
|
|
] @repeat)
|
|
|
|
(if_statement
|
|
[
|
|
"if"
|
|
"elseif"
|
|
"else"
|
|
"then"
|
|
"end"
|
|
] @conditional)
|
|
|
|
(elseif_statement
|
|
[
|
|
"elseif"
|
|
"then"
|
|
"end"
|
|
] @conditional)
|
|
|
|
(else_statement
|
|
[
|
|
"else"
|
|
"end"
|
|
] @conditional)
|
|
|
|
(for_statement
|
|
[
|
|
"for"
|
|
"do"
|
|
"end"
|
|
] @repeat)
|
|
|
|
(function_declaration
|
|
[
|
|
"function"
|
|
"end"
|
|
] @keyword.function)
|
|
|
|
(function_definition
|
|
[
|
|
"function"
|
|
"end"
|
|
] @keyword.function)
|
|
|
|
; Operators
|
|
(binary_expression
|
|
operator: _ @operator)
|
|
|
|
(unary_expression
|
|
operator: _ @operator)
|
|
|
|
"=" @operator
|
|
|
|
[
|
|
"and"
|
|
"not"
|
|
"or"
|
|
] @keyword.operator
|
|
|
|
; Punctuations
|
|
[
|
|
";"
|
|
":"
|
|
","
|
|
"."
|
|
] @punctuation.delimiter
|
|
|
|
; Brackets
|
|
[
|
|
"("
|
|
")"
|
|
"["
|
|
"]"
|
|
"{"
|
|
"}"
|
|
] @punctuation.bracket
|
|
|
|
; Variables
|
|
(identifier) @variable
|
|
|
|
((identifier) @variable.builtin
|
|
(#eq? @variable.builtin "self"))
|
|
|
|
(variable_list
|
|
(attribute
|
|
"<" @punctuation.bracket
|
|
(identifier) @attribute
|
|
">" @punctuation.bracket))
|
|
|
|
; Constants
|
|
((identifier) @constant
|
|
(#match? @constant "^[A-Z][A-Z_0-9]*$"))
|
|
|
|
(vararg_expression) @constant
|
|
|
|
(nil) @constant.builtin
|
|
|
|
[
|
|
(false)
|
|
(true)
|
|
] @boolean
|
|
|
|
; Tables
|
|
(field
|
|
name: (identifier) @field)
|
|
|
|
(dot_index_expression
|
|
field: (identifier) @field)
|
|
|
|
(table_constructor
|
|
[
|
|
"{"
|
|
"}"
|
|
] @constructor)
|
|
|
|
; Functions
|
|
(parameters
|
|
(identifier) @parameter)
|
|
|
|
(function_declaration
|
|
name: [
|
|
(identifier) @function
|
|
(dot_index_expression
|
|
field: (identifier) @function)
|
|
])
|
|
|
|
(function_declaration
|
|
name: (method_index_expression
|
|
method: (identifier) @method))
|
|
|
|
(assignment_statement
|
|
(variable_list
|
|
.
|
|
name: [
|
|
(identifier) @function
|
|
(dot_index_expression
|
|
field: (identifier) @function)
|
|
])
|
|
(expression_list
|
|
.
|
|
value: (function_definition)))
|
|
|
|
(table_constructor
|
|
(field
|
|
name: (identifier) @function
|
|
value: (function_definition)))
|
|
|
|
(function_call
|
|
name: [
|
|
(identifier) @function.call
|
|
(dot_index_expression
|
|
field: (identifier) @function.call)
|
|
(method_index_expression
|
|
method: (identifier) @method.call)
|
|
])
|
|
|
|
(function_call
|
|
(identifier) @function.builtin
|
|
(#any-of? @function.builtin
|
|
; built-in functions in Lua 5.1
|
|
"assert" "collectgarbage" "dofile" "error" "getfenv" "getmetatable" "ipairs" "load" "loadfile"
|
|
"loadstring" "module" "next" "pairs" "pcall" "print" "rawequal" "rawget" "rawset" "require"
|
|
"select" "setfenv" "setmetatable" "tonumber" "tostring" "type" "unpack" "xpcall"))
|
|
|
|
; Others
|
|
(comment) @comment
|
|
|
|
(hash_bang_line) @preproc
|
|
|
|
(number) @number
|
|
|
|
(string) @string
|
|
|
|
(escape_sequence) @string.escape
|